简单高效：不重复随机读取数据库记录 - ASP技术

看到经常有人问这个问题。又到网上找了些看，觉得写得不满意。
大多读取记录到数组里去抽取。昨天又看到人写，心血来潮就顺手想了个，个人认为这种方法应该错吧，呵呵。刚好20行～_～
实现方法：
1。通过recordset游标可移动的特性，在已打开记录集里移动到随机位置读取记录。而且可以将就使用页面中已打开的RS对象。
2。将出现过的随机数保存到一个字符串中，通过instr函数来检查是否重复，重复则递归调用函数至不重复。

数据库打开查询若干，省略... ...
Set rs = Server.CreateObject("Adodb.RecordSet")
rs.open sql,conn,1,1

DIM Appeared
Call DisRndRecord(10,rs.recordCount)'调用函数该位置显示记录

'################SUBS################
'#DisRndRecord(DisNum,rsBound)
'#参数DisNum：显示数量
'#参数rsBound：随机数产生范围
Sub DisRndRecord(DisNum,rsBound)
 DIM i,ThisRnd
 If rsBound < DisNum Then DisNum = rsBound'记录总数小于要抽取记录条数的情况
 For i = 0 To DisNum - 1
  ThisRnd = GetRnd(rsBound)'取得一个不重复的随机数
  rs.Move(ThisRnd)'游标移动到随机数位置数读取
  Response.Write("<br>("&rs("id")&")"&rs("Title"))
  rs.Move(-ThisRnd)
 Next
End Sub
'# 函数GetRnd(bound)返回一个不重复的随机数字
'#参数bound：随机范围
Function GetRnd(bound)
 DIM ranNum
 Randomize()
 ranNum=int(bound*rnd)
 If Instr(Appeared,"["&ranNum&"]") Then'产生的随机数是否出现过
  ranNum = getRnd(bound)
 End If
 Appeared = Appeared & "["&ranNum&"]"'记录已出现的随机数
 GetRnd = ranNum
End Function